数値のべき乗を求めます。
- 構文
- POWER( Base, Exponent )
- 引数
- Base
- 底
- Exponent
- 指数
- 戻値
- BaseのExponent乗の値を返す
べき乗
同じ数を繰り返し掛けたものをべき乗といい、aをn回掛けたものを\(a^n\)と表記します。
このとき\(a\)を底、\(n\)を指数といいます。
例えば2を10回掛けたものは以下のように表します。
\[\underbrace{2 \times 2 \times 2 \times 2 \times 2 \times 2 \times 2 \times 2 \times 2 \times 2}_{10個}=2^{10}\]PRINT POWER(2, 10)負の指数も使えます。
\[a^{-n}=\frac{1}{a^{n}}\]\(2^{-3}\)は以下の様に表します。
\[2^{-3}=\frac{1}{2 \times 2 \times 2}\]PRINT POWER(2, -3)プログラム実行例
ルートの中を簡単にする
\(\sqrt{450000}\)の450000を素因数分解してルートの外に出せる値を外に出す。HASHTBL root
DIM num = 450000
DIM arr = primeFactorization(num)
FOR item IN arr
root[item] = root[item] + 1
NEXT
DIM a = 1, b = 1
FOR n = 0 TO LENGTH(root) - 1
IF INT(root[n, HASH_VAL] / 2) <> 0 THEN a = a * POWER(root[n, HASH_KEY], INT(root[n, HASH_VAL] / 2))
IF (root[n, HASH_KEY] * (root[n, HASH_VAL] MOD 2)) <> 0 THEN b = b * (root[n, HASH_KEY] * (root[n, HASH_VAL] MOD 2))
NEXT
PRINT "√(" + num + ")＝" + IIF(a <> 1, a, "") + IIF(b <> 1, "√(" + b + ")", "")
//////////////////////////////////////////////////
// 【引数】
// array : 要素を追加する配列（参照引数）
// str : 追加する要素
// 【戻値】
// 処理後の配列の中の要素の数
//////////////////////////////////////////////////
FUNCTION arrayPush(var arr[], str)
DIM res = RESIZE(arr, UBound(arr) + 1)
arr[res] = str
RESULT = res + 1
FEND
//////////////////////////////////////////////////
// 【引数】
// expr : 評価する式
// truepart : 評価した式がTrueのときに返す値
// falsepart : 評価した式がFalseのときに返す値
// 【戻値】
// truepart : 評価した式がTrueのとき、falsepart : 評価した式がFalseのとき
//////////////////////////////////////////////////
FUNCTION IIF(expr, truepart, falsepart)
IFB EVAL(expr) THEN
RESULT = truepart
ELSE
RESULT = falsepart
ENDIF
FEND
//////////////////////////////////////////////////
// 【引数】
// num : 素因数分解する数値
// 【戻値】
// 素因数分解した数値を格納した配列
//////////////////////////////////////////////////
FUNCTION primeFactorization(num)
DIM arr[-1]
// 偶数なら2で割り続ける
WHILE num MOD 2 = 0
arrayPush(arr, 2)
num = num / 2
WEND
FOR n = 3 TO num
WHILE num MOD n = 0
arrayPush(arr, n)
num = num / n
WEND
NEXT
RESULT = SLICE(arr)
FEND
//////////////////////////////////////////////////
// 【引数】
// 配列 : 上限値を求める配列
// 【戻値】
// 配列の上限値
//////////////////////////////////////////////////
FUNCTION UBound(array[])
RESULT = RESIZE(array)
FEND- 結果
- √(450000)＝300√(5)
解説
- 1行目
- 「root」という名前の連想配列を宣言する。
HASHTBL root
- 3行目
- 素因数分解してルートの外に出す値を指定。
DIM num = 450000
- 4行目
- primeFactorization関数で450000を素因数分解をしてその結果をarr配列に格納します。例の場合「2,2,2,2,3,3,5,5,5,5,5」が格納されます。
DIM arr = primeFactorization(num)
- 6-8行目
- arr配列に格納されている数値毎に個数をカウント。例の場合{キー, 値} = {2:4, 3:2, 5:5}となります。2が4個、3が2個、5が5個という意味です。
FOR item IN arr root[item] = root[item] + 1 NEXT
- 10行目
- \(a\sqrt{b}\)
DIM a = 1, b = 1
- 12-15行目
- 要素の数だけ配列をループ。
FOR n = 0 TO LENGTH(root) - 1 IF INT(root[n, HASH_VAL] / 2) <> 0 THEN a = a * POWER(root[n, HASH_KEY], INT(root[n, HASH_VAL] / 2)) IF (root[n, HASH_KEY] * (root[n, HASH_VAL] MOD 2)) <> 0 THEN b = b * (root[n, HASH_KEY] * (root[n, HASH_VAL] MOD 2)) NEXT- [値]が2で割り切れなければ
- [キー]の[値を2で割った余り]乗をaに乗算代入する。
カラーコードから抵抗値を計算
HASHTBL color
color["黒"] = 0; color["茶"] = 1; color["赤"] = 2
color["橙"] = 3; color["黄"] = 4; color["緑"] = 5
color["青"] = 6; color["紫"] = 7; color["灰"] = 8
color["白"] = 9; color["金"] = ""; color["銀"] = ""
HASHTBL tolerance
tolerance["黒"] = ""; tolerance["茶"] = 1; tolerance["赤"] = 2
tolerance["橙"] = 0.05; tolerance["黄"] = ""; tolerance["緑"] = 0.5
tolerance["青"] = 0.25; tolerance["紫"] = 0.1; tolerance["灰"] = ""
tolerance["白"] = ""; tolerance["金"] = 5; tolerance["銀"] = 10
DIM str = INPUT("カラーコードを入力してください。")
DIM num = LENGTH(str)
FOR i = 1 TO num - 2
DIM res = res * 10 + color[COPY(str, i, 1)]
NEXT
res = res * POWER(10, color[COPY(str, num - 1, 1)])
PRINT res + "Ω±" + tolerance[COPY(str, num, 1)] + "％以内"- 結果
- INPUT:15 > 黄紫橙金
47000Ω±5％以内
MSGBOXの種別の数値から表示されるボタンを取得
HASHTBL type
type[BTN_YES] = "はい"
type[BTN_NO] = "いいえ"
type[BTN_OK] = "OK"
type[BTN_CANCEL] = "キャンセル"
type[BTN_ABORT] = "中止"
type[BTN_RETRY] = "再試行"
type[BTN_IGNORE] = "無視"
DIM num = INPUT("数値を入力してください。")
IF VAL(num) = ERR_VALUE THEN EXIT
PRINT num
PRINT "----------"
FOR n = 0 TO 6
IF (num AND POWER(2, n)) <> 0 THEN PRINT type[POWER(2, n)]
NEXT
MSGBOX("以下のボタンが表示されます", num)- 結果
- 22
----------
キャンセル
はい
中止
この記事は役に立ちましたか？
