UWSC辞典

境界線の太さを表すXlBorderWeight値を設定または返します。

構文

Borders.Weight

引数

戻値

定数一覧

XlBorderWeight

CONST xlMedium = -4138
CONST xlHairline = 1
CONST xlThin = 2
CONST xlThick = 4

プログラム実行例

表を作成

// XlBordersIndex
CONST xlDiagonalDown = 5
CONST xlEdgeLeft = 7
CONST xlEdgeTop = 8
CONST xlEdgeBottom = 9
CONST xlEdgeRight = 10

// XlLineStyle
CONST xlDouble = -4119
CONST xlContinuous = 1

// XlBorderWeight
CONST xlThick = 4

DIM Excel = ExcelBoot()

WITH Excel
	.Range("B2:F6").Borders.LineStyle = xlContinuous
	.Range("B2:F6").BorderAround(xlContinuous, xlThick)
	.Range("F2:F6").Borders(xlEdgeLeft).LineStyle = xlDouble
	.Range("B6:F6").Borders(xlEdgeTop).LineStyle = xlDouble
	.Range("B2").Borders(xlDiagonalDown).LineStyle = xlContinuous
	WITH .Range("B2:B6").Borders(xlEdgeRight)
		.LineStyle = xlContinuous
		.Weight = xlThick
	ENDWITH
	WITH .Range("B2:F2").Borders(xlEdgeBottom)
		.LineStyle = xlContinuous
		.Weight = xlThick
	ENDWITH
ENDWITH

//////////////////////////////////////////////////
// 【引数】
//   path : 開くファイルのパス名 
// 【戻値】
//   Excelオブジェクト 
//////////////////////////////////////////////////
FUNCTION ExcelBoot(path = "")
	DIM Excel = CREATEOLEOBJ("Excel.Application")
	Excel.Visible = TRUE
	IFB path = "" THEN
		Excel.Workbooks.Add
	ELSE
		DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
		IFB FSO.GetParentFolderName(path) = "" THEN
			path = GET_CUR_DIR + "\" + path
		ENDIF
		Excel.Workbooks.Open(path)
	ENDIF
	RESULT = Excel
FEND

1. com.Excel.Range（）
2. com.Excel.Borders.LineStyle（）
3. com.Excel.Borders.Weight（）

結果

解説

1. 18行目

   	.Range("B2:F6").Borders.LineStyle = xlContinuous
   

   セル範囲B2:F6に格子の罫線を引きます。

2. 19行目

   	.Range("B2:F6").BorderAround(xlContinuous, xlThick)
   

   セル範囲B2:F6に太線で外枠罫線を引きます。

3. 20行目

   	.Range("F2:F6").Borders(xlEdgeLeft).LineStyle = xlDouble
   

   セル範囲F2:F6に2本線の左罫線を引きます。

4. 21行目

   	.Range("B6:F6").Borders(xlEdgeTop).LineStyle = xlDouble
   

   セル範囲B6:F6に2本線の上罫線を引きます。

5. 22行目

   	.Range("B2").Borders(xlDiagonalDown).LineStyle = xlContinuous
   

   セルB2に左上から右下の斜線を引きます。

6. 23-26行目

   	WITH .Range("B2:B6").Borders(xlEdgeRight)
   		.LineStyle = xlContinuous
   		.Weight = xlThick
   	ENDWITH
   

   セル範囲B2:B6に太線で右罫線を引きます。

7. 27-30行目

   	WITH .Range("B2:F2").Borders(xlEdgeBottom)
   		.LineStyle = xlContinuous
   		.Weight = xlThick
   	ENDWITH
   

   セル範囲B2:F2に太線で下罫線を引きます。

-PR-