LineStyle

タグ:

罫線または輪郭線の種類を設定します。

構文
Borders.LineStyle
引数
戻値

定数一覧

XlBordersIndex

名前値説明
xlDiagonalDown5範囲内の各セルの左上隅から右下方向に実行される罫線。
xlDiagonalUp6範囲内の各セルの左下隅から右上への罫線。
xlEdgeLeft7範囲内の左端の罫線
xlEdgeTop8範囲内の上側の罫線
xlEdgeBottom9範囲内の下側の罫線
xlEdgeRight10範囲の右端の罫線
xlInsideVertical11範囲外の罫線を除く、範囲内のすべてのセルの垂直罫線
xlInsideHorizontal12範囲外の罫線を除く、範囲内のすべてのセルの水平罫線
CONST xlDiagonalDown = 5
CONST xlDiagonalUp = 6
CONST xlEdgeLeft = 7
CONST xlEdgeTop = 8
CONST xlEdgeBottom = 9
CONST xlEdgeRight = 10
CONST xlInsideVertical = 11
CONST xlInsideHorizontal = 12

XlLineStyle

名前値説明
xlLineStyleNone-4142線なし
xlDouble-41192本線
xlDot-4118点線
xlDash-4115破線
xlContinuous1実線
xlDashDot4一点鎖線
xlDashDotDot5ニ点鎖線
xlSlantDashDot13斜破線
CONST xlLineStyleNone = -4142
CONST xlDouble = -4119
CONST xlDot = -4118
CONST xlDash = -4115
CONST xlContinuous = 1
CONST xlDashDot = 4
CONST xlDashDotDot = 5
CONST xlSlantDashDot = 13

プログラム実行例

罫線を引く

CONST xlEdgeTop = 8
CONST xlDiagonalUp = 6
CONST xlDouble = -4119
CONST xlDash = -4115
CONST xlContinuous = 1

DIM Excel = ExcelBoot()

WITH Excel
	.Range("B2").Borders.LineStyle = xlContinuous
	.Range("B4").Borders(xlEdgeTop).LineStyle = xlDash
	.Range("B6").Borders(xlDiagonalUp).LineStyle = xlDouble
	.Range("D2:F6").Borders.LineStyle = xlContinuous
ENDWITH

//////////////////////////////////////////////////
// 【引数】
//   path : 開くファイルのパス名 
// 【戻値】
//   Excelオブジェクト 
//////////////////////////////////////////////////
FUNCTION ExcelBoot(path = "")
	DIM Excel = CREATEOLEOBJ("Excel.Application")
	Excel.Visible = TRUE
	IFB path = "" THEN
		Excel.Workbooks.Add
	ELSE
		DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
		IFB FSO.GetParentFolderName(path) = "" THEN
			path = GET_CUR_DIR + "\" + path
		ENDIF
		Excel.Workbooks.Open(path)
	ENDIF
	RESULT = Excel
FEND
  1. ExcelBoot
  2. Excel.Borders.LineStyle

表を作成

// XlBordersIndex
CONST xlDiagonalDown = 5
CONST xlEdgeLeft = 7
CONST xlEdgeTop = 8
CONST xlEdgeBottom = 9
CONST xlEdgeRight = 10

// XlLineStyle
CONST xlDouble = -4119
CONST xlContinuous = 1

// XlBorderWeight
CONST xlThick = 4

DIM Excel = ExcelBoot()

WITH Excel
	.Range("B2:F6").Borders.LineStyle = xlContinuous
	.Range("B2:F6").BorderAround(xlContinuous, xlThick)
	.Range("F2:F6").Borders(xlEdgeLeft).LineStyle = xlDouble
	.Range("B6:F6").Borders(xlEdgeTop).LineStyle = xlDouble
	.Range("B2").Borders(xlDiagonalDown).LineStyle = xlContinuous
	WITH .Range("B2:B6").Borders(xlEdgeRight)
		.LineStyle = xlContinuous
		.Weight = xlThick
	ENDWITH
	WITH .Range("B2:F2").Borders(xlEdgeBottom)
		.LineStyle = xlContinuous
		.Weight = xlThick
	ENDWITH
ENDWITH

//////////////////////////////////////////////////
// 【引数】
//   path : 開くファイルのパス名 
// 【戻値】
//   Excelオブジェクト 
//////////////////////////////////////////////////
FUNCTION ExcelBoot(path = "")
	DIM Excel = CREATEOLEOBJ("Excel.Application")
	Excel.Visible = TRUE
	IFB path = "" THEN
		Excel.Workbooks.Add
	ELSE
		DIM FSO = CREATEOLEOBJ("Scripting.FileSystemObject")
		IFB FSO.GetParentFolderName(path) = "" THEN
			path = GET_CUR_DIR + "\" + path
		ENDIF
		Excel.Workbooks.Open(path)
	ENDIF
	RESULT = Excel
FEND
  1. Excel.Range
  2. Excel.Range.Borders
  3. Excel.Borders.LineStyle
  4. Excel.Borders.Weight
結果
解説
  1. 18行目
    	.Range("B2:F6").Borders.LineStyle = xlContinuous
    セル範囲B2:F6に格子の罫線を引きます。
  2. 19行目
    	.Range("B2:F6").BorderAround(xlContinuous, xlThick)
    セル範囲B2:F6に太線で外枠罫線を引きます。
  3. 20行目
    	.Range("F2:F6").Borders(xlEdgeLeft).LineStyle = xlDouble
    セル範囲F2:F6に2本線の左罫線を引きます。
  4. 21行目
    	.Range("B6:F6").Borders(xlEdgeTop).LineStyle = xlDouble
    セル範囲B6:F6に2本線の上罫線を引きます。
  5. 22行目
    	.Range("B2").Borders(xlDiagonalDown).LineStyle = xlContinuous
    セルB2に左上から右下の斜線を引きます。
  6. 23-26行目
    	WITH .Range("B2:B6").Borders(xlEdgeRight)
		.LineStyle = xlContinuous
		.Weight = xlThick
	ENDWITH
    セル範囲B2:B6に太線で右罫線を引きます。
  7. 27-30行目
    	WITH .Range("B2:F2").Borders(xlEdgeBottom)
		.LineStyle = xlContinuous
		.Weight = xlThick
	ENDWITH
    セル範囲B2:F2に太線で下罫線を引きます。